Calcolo della PASQUA

A differenza di altre festività, la data in cui cade la Pasqua cambia ogni anno. Questa festività è stabilita attraverso uno calcolo specifico: cade la domenica successiva al primo plenilunio dopo l’equinozio di primavera. Questo fa si che tale ricorrenza si festeggi in un arco di tempo che va dal 22 marzo al 25 aprile. 

Ok, fatta questa premessa come possiamo utilizzare Excel per determinarne la data in base ad un anno specifico?

Seguiremo un metodo che fu escogitato dal matematico tedesco Carl Gauss, esso prevede l’uso di numerose variabili e diversi passaggi per giungere all’obiettivo, quindi iniziamo.

Secondo questo metodo bisogna determinare il valore di due parametri che vengono indicati con le lettere M ed N.

Il calendario gregoriano prevede che i valori M ed N siano quelli indicati in tabella a seconda degli anni considerati.

Anni M N
1583-1699 22 2
1700-1799 23 3
1800-1899 23 4
1900-2099 24 5
2100-2199 24 6
2200-2299 25 0
2300-2399 26 1
2400-2499 25 1

Con i passaggi successivi andremo a determinare altri parametri. Usando la funzione RESTO, tema già trattato in questo canale, determineremo i valori a, b e c nel seguente modo:

Dividiamo l’anno di nostro interesse per il numero 19 ed il resto della divisione corrisponderà al parametro a

Nella cella F11 scriviamo la funzione:

=RESTO(F1;19)


Ora dividiamo l’anno per il numero 4 ed il resto della divisione corrisponderà al parametro b

Nella cella F12 scriviamo la funzione:

=RESTO(F1;4)


Il parametro c sarà dato dal resto della divisione fra anno ed il numero 7

Nella cella F13 scriviamo la funzione:

=RESTO(F1;7)


I successivi 2 parametri prevedono un calcolo un po’ lungo ma nulla di eccessivamente complesso.

Moltiplichiamo il numero 19 con il valore a e sommiamo il parametro M, quindi dividiamo il tutto per 30, il resto della divisione sarà il parametro d

Nella cella F14 scomodando sempre la funzione RESTO scriviamo:

=RESTO(19*F11+24;30)


Per l’ultimo parametro seguiamo questa formula:

(2 * b + 4 * c + 6 * d + N) mod 7

Quindi nella cella F15 scriviamo:

=RESTO(2*F12+4*F13+6*F14+5;7)


Grazie a questi numerosi parametri saremo in grado di determinare giorno e mese.

Se la somma dei parametri d + e è < di 10 allora la Pasqua cadrà il giorno dato dalla somma di d + e + 22 del mese di marzo, in caso contrario si verificherà il giorno dato dalla somma dei parametri d + e a cui andremo a sottrarre il numero 9, in questo caso nel mese di aprile.

Tramutiamo in formula quello che abbiamo appena detto per determinare il giorno, quindi nella cella F17 usando la funzione SE scriviamo:

=SE((F14+F15)<10;F14+F15+22;F14+F15-9)


Mentre per determinare il mese nella cella F18, sempre con la funzione SE scriviamo:

=SE((F14+F15)<10;3;4)


Per completare il tutto usiamo la funzione DATA per mettere insieme giorno, mese ed anno, in B20 scriviamo:

=DATA(F1;F18;F17)


Ad essere onesti non abbiamo ancora terminato il calcolo, o meglio il calcolo è completo ma nel caso si verificassero un paio di eccezioni, dobbiamo correggere la data.

La prima eccezione si verifica nel caso in cui il risultato ottenuto corrisponda al 26 di aprile, in tal caso correggeremo la data sottraendo 7 giorni, facendo cadere la Pasqua il 19 aprile.

Per fare questo nella cella B21 scriviamo:

=SE(E(F17=26;F18=4);B20-7;B20)


La seconda eccezione è molto più specifica, quindi prestate attenzione, si verifica nel caso in cui il risultato ottenuto corrisponda al 25 di aprile, e contemporaneamente il parametro a sia >10, d = 28 ed infine e = 6, anche in questo caso correggeremo la data sottraendo 7 giorni, facendo cadere la Pasqua il 18 aprile.

Riportiamoci nella cella B21 e sistemiamo la formula nel seguente modo:

=SE(E(F17=26;F18=4);B20-7;SE(E(F17=25;F18=4;F11>10;F14=28;F15=6);B20-7;B20))


Giusto per essere sicuri che il tutto funzioni correttamente, proviamo ad inserire l’anno 2049 che presenta la seconda eccezione, come potete vedere la data contenuta nella cella B21, viene corretta scalando 7 giorni dalla data contenuta nella cella B20.

Nel video qui sotto trovate tutti i passaggi appena illustrati, buona visione.